Have you ever needed to export the email addresses of your Outlook contacts to a text file? One of the visitors here was needing to do this. So I modified the script I wrote that exports contacts to vcf files to create a text file that just contains the email addresses of all of the contacts. This script takes one command line argument, the path where the test file will be stored. It then opens your Outlook contacts and extracts the email addresses for each contact and writes those addresses to a file named emailaddress.txt

[More:]

This script only works if you run it from a command prompt using cscript. The following is an example of executing this script.

C:\scripts>cscript exportContacts.vbs /p:C:\scripts\outlookContacts
Microsoft (R) Windows Script Host Version 5.6
Copyright (C) Microsoft Corporation 1996-2001. All rights reserved.

This sample script uses the named command line arguments to pass the domain information to script. This is the domain that will be checked for type, native or mixed mode.

'==========================================================
'==     Extract Contact Email Addresses Script Sample
'==
'==           Copyright © 2009, Dave Moats
'==
'== This sample is provided <b>'AS-IS'</b>, without any
'== express or implied warranty. In no event will the
'== authors be held liable for any damages arising from
'== the use of this sample code.
'==
'== Permission is granted to anyone to use this sample
'== code for any purpose, including commercial applications,
'== subject to the following restrictions:
'==
'== The origin of this code must not be misrepresented;
'== you must not claim that you wrote the original code.
'==
'== If you use this code, an acknowledgment in the
'== documentation is requested - shown below:
'==
'==             Portions Copyright © 2009,
'==        Dave Moats (http://www.davemoats.com/).
'==
'==========================================================

'==========================================================
'== NOTE: watch for wrapped lines and html special
'==        characters in the web representation of this
'==        sample code
'==========================================================

'==========================================================
'==
'== exportContacts.vbs - a script used to export contacts
'==                        from outlook and save them in
'==                        vcf format
'==========================================================
option explicit

'==========================================================
'== declare the local variables to be used
'==========================================================
dim scriptName, namedArgs, folderPath

'==========================================================
'== get the name of the running script
'==========================================================
scriptName = wscript.scriptname

'==========================================================
'== get the named command line arguments
'==========================================================
set namedArgs = wscript.arguments.named

if not namedArgs.exists("p") then
   wscript.echo "Usage: " & scriptName & " /p:<output folder path> is required"
   wscript.echo "Example: cscript " & scriptName & " /p:c:\path to the folder"
   wscript.quit
else
   folderPath = namedArgs.item("p")
end if

set namedArgs = nothing

'==========================================================
'== now call the subroutine that does all the work
'==========================================================
exportAddresses folderPath

wscript.quit

'==========================================================
'== sub exportAddresses - subroutine that connects to outlook
'==                   and exports all contacts email addresses
'==                   to a file in the folder specified by the exportPath argument
'==========================================================
sub exportAddresses(exportPath)

    '======================================================
    '== declare the local variables
    '======================================================
    dim outApp, fldContacts, contactEntry, fso, outFile

    '======================================================
    '== create the outlook object and then get the contacts
    '======================================================
    set outApp = createobject("Outlook.Application")
    set fldContacts = outApp.getnamespace("MAPI").getdefaultfolder(10)

    '======================================================
    '== here we are looping the entries in the contacts
    '== folder looking for contacts - when a contact is
    '== found it will be exported
    '======================================================
    set fso = createobject( "Scripting.FileSystemObject" )
    set outFile = fso.createtextfile( exportPath & "\emailaddreses.txt", 8 )

    for each contactEntry in fldContacts.items
       if typename(contactEntry) = "ContactItem" then

          dim tmpString1, tmpString2, tmpString3, outMsg

          tmpString1 = contactEntry.email1address
          tmpString2 = contactEntry.email2address
          tmpString3 = contactEntry.email3address

          if tmpString1 <> "" then
             outMsg = tmpString1
          end if

          if tmpString2 <> "" then
             outMsg = outMsg & vbcrlf & tmpString2
          end if

          if tmpString3 <> "" then
             outMsg = outMsg & vbcrlf & tmpString3
          end if

          outFile.writeline outMsg

       end if
    next

    outFile.close
    set outFile = nothing
    set fso = nothing
    '======================================================
    '== dumping the object references that were created
    '======================================================
    set fldContacts = nothing
    set outApp = nothing

end sub

Pay close attention to the lines wrapping in this sample, the script does not have any multi-line statements.

I hope this post helped out. If it didn't, I am always looking for new scripts to add so submit a request for your question or need and I will see if I can answer it.

Dave